إنشاء لعبة كلمات داخل Excel لم يعد فكرة تقنية معقدة، بل أصبح مشروعًا بسيطًا يعتمد على دوال منطقية وأدوات التنسيق وديناميكية الجداول. يجمع Excel بين معالجة النصوص، التحكم بالمدخلات، وربط النتائج بقواعد شرطية تتيح تصميم تجربة تفاعلية تشبه الألعاب المنتشرة على الإنترنت. يمكن للمستخدم بناء لوحة لعب، تحديد الإجابات، إضافة رسائل فوز أو خطأ، وجعل كل خطوة تعتمد على صيغ ذكية تعمل تلقائيًا. هذا الأسلوب يمنح Excel قدرة أكبر من الجداول التقليدية، ويحوّله إلى منصة صغيرة لصناعة ألعاب نصيّة تفاعلية تجذب المتعلمين والمستخدمين الباحثين عن أساليب جديدة للإبداع والاختبار.
أحب استخدام Excel لأغراض خارج نطاق المحاسبة المملة. إنشاء نسخة طبق الأصل من Wordle تعمل بكامل طاقتها، وقابلة لإعادة الاستخدام والمشاركة، هو أحد هذه الأمور. علاوة على ذلك، إنها طريقة ممتعة وفريدة لإتقان أدوات Excel الأساسية.
تستخدم هذه الطريقة وحدات ماكرو VBA.
تستخدم الخطوة الرئيسية في هذا الدليل وحدات ماكرو VBA للتعامل مع تسلسل تخمين Wordle المعقد ومنطق التسجيل. يضمن هذا للاعب تجربةً أكثر موثوقية، حيث لا يتطلب منه تغيير أي من إعدادات Excel الأساسية. مع ذلك، لا تقلق إذا كنت لا تعرف كيفية كتابة شيفرة VBA، فيمكنك ببساطة نسخ ولصق شيفرتي!
عندما يفتح اللاعب الملف المُفعّل فيه وحدات الماكرو، سيظهر شريط تحذير أمني أعلى شاشة Excel. عند هذه النقطة، يجب عليه النقر على “تمكين المحتوى” لكي تعمل اللعبة كما هو متوقع. إذا لم يفعل، فستبقى اللوحة ثابتة ولن تُسجّل تخميناته.
يجب عليك أنت واللاعبون الذين سيحصلون على نسخة من لعبتك استخدام إصدار سطح المكتب من Microsoft Excel.
الخطوة 1: حفظ الملف المُفعّل بوحدات الماكرو
تُهيئ هذه الخطوة مُصنّف عملك لـ VBA. افتح مُصنّف Excel جديد، ثم انقر على “ملف” > “حفظ باسم” > “استعراض”.
اختر موقعًا لملفك، وفي حقل “حفظ باسم النوع”، حدد “مصنف Excel مُمكّن بوحدات الماكرو”. ثم، سمِّ الملف، وانقر على “حفظ“.
الخطوة 2: إعداد القاموس واللوحة
بعد ذلك، عليك إنشاء قاموس للكلمات الصحيحة وإنشاء لوحة لعبة Wordle.
أضف ورقة عمل جديدة (“+”)، وانقر نقرًا مزدوجًا فوق علامة تبويب الورقة الجديدة لإعادة تسميتها إلى WordList. اضغط على Enter للتأكيد.
ابحث عن قائمة كلمات من خمسة أحرف، وانسخ جميع الكلمات، ثم ألصقها (باستخدام Ctrl+Shift+V) في الخلية A1 من ورقة قائمة الكلمات. ثم ابحث عن الكلمات المكررة واحذفها تمامًا بتحديد العمود A والنقر على “إزالة الكلمات المكررة” في علامة تبويب “البيانات”.
بعد ذلك، ارجع إلى ورقة عمل اللعبة (Sheet1)، وحدد جميع الخلايا (Ctrl+A)، وقم بتغيير عرض الخلايا إلى 65 بكسل عن طريق النقر فوق الحد الفاصل بين عنواني العمود وسحبه.
كرر هذه العملية للصفوف لجعل جميع الخلايا مربعة.
الآن، أدخل كلمة سرية من خمسة أحرف في الخلية A1 بأحرف كبيرة. ثم حدد الخلايا من B3 إلى F8، وغيّر حجم الخط إلى 36 نقطة، وقم بمحاذاة النص عموديًا وأفقيًا من خلال علامة التبويب “الصفحة الرئيسية”. وأخيرًا، أضف إطارًا خارجيًا.
اضغط على Ctrl+S لحفظ الملف.
الخطوة 3: إنشاء آليات اللعبة
الماكرو هو جوهر اللعبة، فهو يتحكم تلقائيًا بجميع عمليات التسجيل والألوان ومنطق الحروف.
انقر بزر الماوس الأيمن على علامة التبويب “الورقة 1” ثم انقر على “عرض الكود”.
في نافذة محرر VBA، انقر نقرًا مزدوجًا فوق “Sheet1 (Sheet1)” ضمن كائنات Microsoft Excel، ثم انسخ وألصق الكود أدناه في منطقة الوحدة الفارغة إلى اليمين.
Private Sub Worksheet_Change(ByVal Target As Range)
Dim GuessRow As Long
Dim SecretWord As String
‘ Only run if the changed cell is the F-column (the fifth letter of a guess)
If Not Intersect(Target, Me.Range(“F3:F8”)) Is Nothing Then
Application.ScreenUpdating = False
Application.EnableEvents = False
‘ CRITICAL: Unprotect the sheet to allow the macro to change colors and lock status
If Me.ProtectContents Then Me.Unprotect “YOUR_PASSWORD”
GuessRow = Target.Row
‘ 1. Get Secret Word and Guess
SecretWord = UCase(Me.Range(“A1”).Value)
‘ Concatenate the 5 cells into a single string
Dim InputWord As String
Dim j As Long
For j = 2 To 6 ‘ Loop through columns B to F
InputWord = InputWord & Me.Cells(GuessRow, j).Value
Next j
Dim GuessWord As String
GuessWord = UCase(InputWord)
‘ 2. Check if valid word (using COUNTIF trick)
Dim WordCount As Long
WordCount = Application.WorksheetFunction.CountIf( _
Sheets(“WordList”).Range(“A:A”), GuessWord)
If WordCount = 0 Then
‘ Handle invalid word (Not in word list)
MsgBox “Not in word list! Please try again.”, vbExclamation
Me.Range(“B” & GuessRow & “:F” & GuessRow).ClearContents
Else
‘ NEW CHECK: Check for duplicate entry
Dim r As Long
Dim DuplicateFound As Boolean
DuplicateFound = False
‘ Loop through all *previous* guess rows (from row 3 up to the current row – 1)
For r = 3 To GuessRow – 1
‘ Concatenate the word from the previous row for comparison
Dim PreviousWord As String
Dim k As Long
For k = 2 To 6 ‘ Columns B to F
PreviousWord = PreviousWord & Me.Cells(r, k).Value
Next k
‘ Compare the uppercase current guess (GuessWord) with the previous guess
If GuessWord = UCase(PreviousWord) Then
DuplicateFound = True
Exit For
End If
PreviousWord = “” ‘ Reset for the next loop iteration
Next r
If DuplicateFound Then
MsgBox “You already guessed that word! Please try again.”, vbExclamation
Me.Range(“B” & GuessRow & “:F” & GuessRow).ClearContents
‘ Restore settings and exit sub after duplicate is cleared
Application.EnableEvents = True
Application.ScreenUpdating = True
Me.Protect “YOUR_PASSWORD”
Exit Sub
End If
‘ 3. Core Wordle Scoring Logic (Sets the cell colors directly)
Dim i As Long
Dim Letter As String
Dim ClaimedLetters As String
ClaimedLetters = SecretWord ‘ Start with all letters available
‘ Pass 1: Check for GREEN (Correct Position)
For i = 1 To 5 ‘ Columns 2 (B) to 6 (F)
‘ FIX: Convert cell content to uppercase for scoring comparison
Letter = UCase(Me.Cells(GuessRow, i + 1).Value)
If Mid(SecretWord, i, 1) = Letter Then
Me.Cells(GuessRow, i + 1).Interior.Color = RGB(106, 170, 100) ‘ Green
Mid(ClaimedLetters, i, 1) = “#” ‘ Use placeholder to claim the letter
End If
Next i
‘ Pass 2: Check for YELLOW/GRAY
For i = 1 To 5
‘ FIX: Convert cell content to uppercase for scoring comparison
Letter = UCase(Me.Cells(GuessRow, i + 1).Value)
‘ Only score if not already colored GREEN
If Me.Cells(GuessRow, i + 1).Interior.Color <> RGB(106, 170, 100) Then
‘ Search the remaining (non-Green) available letters
If InStr(1, ClaimedLetters, Letter) > 0 Then
Me.Cells(GuessRow, i + 1).Interior.Color = RGB(201, 180, 88) ‘ Yellow
‘ Claim this yellow letter instance
Mid(ClaimedLetters, InStr(1, ClaimedLetters, Letter), 1) = “#”
Else
Me.Cells(GuessRow, i + 1).Interior.Color = RGB(120, 124, 126) ‘ Gray
End If
End If
Next i
‘ 4. Check for Win/Loss (Win check is done via color)
Dim isWin As Boolean
isWin = True
For i = 2 To 6
If Me.Cells(GuessRow, i).Interior.Color <> RGB(106, 170, 100) Then
isWin = False
Exit For
End If
Next i
If isWin Then
Me.Range(“B2”).Value = “YOU WIN!”
‘ FIX: Loss condition added for the final row (Row 8)
ElseIf GuessRow = 8 Then
Me.Range(“B2”).Value = “Better luck next time. The word was ” & SecretWord
End If
‘ 5. LOCK THE CURRENT ROW and UNLOCK THE NEXT ROW for sequential play
Me.Range(“B” & GuessRow & “:F” & GuessRow).Locked = True ‘ Lock the row just completed
‘ Only unlock the next row if the game isn’t won and there are more rows
If Not isWin And GuessRow < 8 Then
Me.Range(“B” & (GuessRow + 1) & “:F” & (GuessRow + 1)).Locked = False ‘ Unlock the next row
End If
End If
Me.Protect “YOUR_PASSWORD” ‘ Re-protect the sheet using the password you set
Application.EnableEvents = True
Application.ScreenUpdating = True
End If
‘ If the sheet was already protected, this ensures it gets protected again even if the IF block above was skipped.
If Not Me.ProtectContents Then Me.Protect “YOUR_PASSWORD”
End Sub
الآن، مع استمرار فتح نافذة VBA، اضغط على Ctrl+H لفتح نافذة الاستبدال. في حقل “البحث عن”، اكتب YOUR_PASSWORD، وفي حقل “استبدال بـ”، اكتب كلمة مرور ستستخدمها لاحقًا لتأمين ورقة العمل. دوّن هذا! ثم انقر على “استبدال الكل”، وسترى كلمة المرور قد استُبدلت أربع مرات.
أغلق نافذة الاستبدال.
بما أن السطر الأول من الكود يحتوي على مُعالِج أحداث يُفعَّل تلقائيًا عند تعديل أي خلايا، يجب عليك تعطيله مؤقتًا حتى تنتهي من إعداد جدول البيانات. للقيام بذلك، مع استمرار فتح نافذة VBA، انقر على “عرض” في الشريط، ثم اختر “نافذة فورية”.
بعد ذلك، انسخ وألصق ما يلي في النافذة الفورية، واضغط على Enter:
Application.EnableEvents = False
صغّر نافذة VBA للعودة إلى ورقة عمل Wordle. اضغط على Ctrl+S لحفظ الملف.
تحذير
لا تُخمّن على لوحة اللعبة الآن! سنختبر وظائف ورقة العمل في الخطوة 7.
الخطوة 4: تقييد مدخلات اللاعب
بعد ذلك، عليك التحكم في كيفية إدخال اللاعب لمدخلاته. بمعنى آخر، تريد إجباره على إدخال حرف واحد في كل خلية، بدلاً من كتابة الكلمة كاملةً دفعةً واحدة.
يمكن دمج هذه الخطوة في شيفرة VBA، ولكن هناك بعض الأسباب التي تجعلني أفضل استخدام التحقق من صحة البيانات:
- يتلقى اللاعب ملاحظات حول المدخلات غير الصحيحة قبل قبول المدخلات (يعمل الماكرو فقط بعد تغيير قيمة الخلية).
- التحقق من صحة البيانات ميزة أساسية في Excel لا تستغرق وقتًا طويلاً في المعالجة (يجب تهيئة الماكرو، والتحقق من مدخلات الخلية، ثم مسحها، مما يستغرق وقتًا أطول ويستهلك موارد أكثر).
- استخدام التحقق من صحة البيانات سهل للغاية – صيغة بسيطة واحدة تُعالج جميع خلايا لوحة اللعبة (يتطلب ماكرو VBA تعليمات برمجية معقدة إضافية).
حدد الخلايا من B3 إلى F8، ثم انقر على أيقونة “التحقق من صحة البيانات” في علامة التبويب “البيانات” على الشريط.
الآن، حدد “مخصص” من القائمة المنسدلة “السماح“، ثم انسخ ما يلي في حقل الصيغة:
=AND(LEN(B3)=1,ISERROR(VALUE(B3)))
الخطوة 5: إضافة تعليمات اللعبة
تضيف هذه الخطوة جودة بصرية للعبة من خلال توجيه اللاعب لكيفية اللعب.
انسخ الصيغة التالية، وألصقها في الخلية B2:
=" Guess the 5-letter word. Type one letter per cell and use the Right Arrow key to navigate."
ملاحظة
أضفتُ مسافةً عمدًا قبل كلمة “Guess” لمنع تفعيل الإكمال التلقائي في Excel عند كتابة الحرف “G” كأول حرف من التخمين.
بعد ذلك، حدد الخلايا من B2 إلى F2، ثم انقر على “دمج وتوسيط” ثم “التفاف النص” في علامة التبويب “الصفحة الرئيسية”.
اضغط على Ctrl+S لحفظ الملف.
الخطوة 6: تحسين اللعبة وحمايتها
أنت على وشك الانتهاء، ولكن هناك بعض الخطوات السريعة الأخرى التي يجب القيام بها قبل اختبار اللعبة وإرسالها إلى أصدقائك.
أولاً، أخفِ كلمة المرور بالنقر بزر الماوس الأيمن على عنوان الصف 1 واختيار “إخفاء”. سيؤدي هذا أيضًا إلى رفع شبكة اللعبة إلى أعلى الشاشة.
بعد ذلك، تأكد من أن اللاعب يستطيع تحديد خلايا الصف الأول فقط عند بدء اللعب (سيتولى VBA التنقل التسلسلي بعد الانتهاء من التخمين الأول). حدد الخلايا من B3 إلى F3، واضغط على Ctrl+1 لفتح مربع حوار “تنسيق الخلايا”. افتح علامة التبويب “الحماية”، وألغِ تحديد “مُؤمَّن”، ثم انقر على “موافق”.
جميع الخلايا الأخرى مقفلة افتراضيًا عند بدء اللعبة، لذا يمكنك الآن حماية ورقة العمل. في علامة التبويب “مراجعة”، انقر على “حماية ورقة العمل”. ثم اكتب كلمة المرور التي أضفتها إلى الكود في الخطوة 3، وتأكد من تحديد الخيارات التالية فقط:
- حماية ورقة العمل ومحتويات الخلايا المقفلة
- تحديد الخلايا غير المقفلة
انقر على “موافق” وأكّد كلمة المرور.
بعد ذلك، احمِ ورقة عمل WordList، مع تحديد “حماية ورقة العمل ومحتويات الخلايا المقفلة” فقط.
الآن، ارجع إلى الورقة 1، وفي علامة التبويب “عرض”، قم بإلغاء تحديد “العناوين”.
أخيرًا، ارجع إلى نافذة VBA التي صغّرتها سابقًا، وفي النافذة الفورية، استبدل كلمة “False” بـ “True”، ثم اضغط على Enter. سيبدأ الكود بالعمل.
احفظ وأغلق نافذة VBA بالكامل، ثم اضغط على Ctrl+S لحفظ الملف.
الخطوة 7: إنشاء نسخة تجريبية
في هذه المرحلة، ربما ترغب في اختبار اللعبة. مع ذلك، لا تفعل ذلك في الإصدار الحالي من الملف! أنشئ نسخة.
أغلق Excel، وحدد المجلد الذي حفظت فيه مصنف الماكرو. ثم حدد الملف واضغط على Ctrl+C > Ctrl+V لنسخه.
الآن، افتح النسخة، وانقر على “تمكين المحتوى”.
جرّب لوحة اللعبة: اكتب كلمة غير صحيحة، أدخل أكثر من حرف في خلية، راقب ما يحدث عند إنهاء صف، استخدم أحرفًا صغيرة، كرّر كلمة، وهكذا.
الخطوة 8: إرسال اللعبة إلى أصدقائك
أفضل ما في إنشاء لعبة فيروسية هو مشاركتها! بما أن اللعبة بأكملها موجودة في ملف Excel واحد، فإن المشاركة بسيطة، ولكن يجب التأكد من إرسال نسخة (بدلاً من رابط المشاركة) من المصنف الأصلي، مثلاً عبر مرفق بريد إلكتروني – فأنت لا تريد أن يلعب الجميع على نفس الإصدار! تذكر أيضًا إخبار اللاعبين بضرورة النقر على “تفعيل المحتوى” عند فتح مصنف اللعبة. لا تتردد في نسخ لقطة الشاشة أعلاه لتوضيح ذلك.
الخطوة 9: إعادة ضبط الكلمة والرسالة
بما أنك أنشأت نسخة تجريبية في الخطوة 7، فمن المفترض أن تكون الشبكة في النسخة الأصلية واضحة. لذلك، عند إنشاء لعبة جديدة في اليوم التالي، ما عليك سوى إعادة ضبط كلمة المرور. مع ذلك، يجب عليك تعطيل وحدات الماكرو مؤقتًا للقيام بذلك.
افتح المصنف الأصلي، وانقر على “تمكين المحتوى”. ثم في الورقة 1، انقر على “إلغاء حماية الورقة” في علامة التبويب “مراجعة”، واكتب كلمة المرور، ثم انقر على “موافق“.
بعد ذلك، انقر بزر الماوس الأيمن على علامة التبويب “Sheet1” وانقر على “عرض الكود”. ثم انقر على “عرض” في شريط نافذة VBA، وحدد “النافذة الفورية”، واكتب ما يلي واضغط على Enter:
Application.EnableEvents = False
الآن، اكتب كلمة جديدة في الخلية A1 باستخدام الأحرف الكبيرة، وأخفِ الصف الأول، واحذف العناوين، وأعد تعيين كلمة المرور عبر “حماية ورقة العمل”، مع التأكد من تحديد “حماية ورقة العمل ومحتويات الخلايا المقفلة” و”تحديد الخلايا غير المقفلة” فقط.
ارجع إلى النافذة الفورية، واستبدل “خطأ” بـ “صحيح”، واضغط على Enter، وأغلق نافذة VBA.
اضغط على Ctrl+S لحفظ الملف، ثم أغلق Excel، وأرسل اللعبة الجديدة إلى أصدقائك.
إنشاء لوحة Wordle كاملة ليس الطريقة الوحيدة التي أستمتع بها باستخدام Microsoft Excel. لأصدقائي الذين يفضلون التحدي، أستخدم البرنامج لإنشاء ألغاز كلمات متقاطعة قابلة للطباعة، مستفيدًا من أدوات بسيطة مثل التنسيق الدقيق للخلايا، وتلوينها، وحدودها.
تحويل Excel إلى منصة لإنشاء لعبة كلمات لا يتطلب خبرة برمجية، بل فهمًا للدوال الأساسية والقدرة على استخدام التنسيقات بذكاء. يساعد هذا النوع من المشاريع في تعزيز المهارات المنطقية، ويقدّم طريقة ممتعة للتعلم أو الاختبار أو المشاركة مع الآخرين. بإضافة بعض اللمسات الإبداعية يمكن بناء لعبة قابلة للتطوير والتخصيص بسهولة، مما يبرز قوة Excel كأداة تتجاوز الجداول التقليدية.
